Did you know ... Search Documentation:
Predicate file_search_path/2
Sourcefile_search_path(+Alias, -Path)
Dynamic multifile hook predicate used to specify‘path aliases’. This hook is called by absolute_file_name/3 to search files specified as Alias(Name), e.g., library(lists). This feature is best described using an example. Given the definition: 
file_search_path(demo, '/usr/lib/prolog/demo').

the file specification demo(myfile) will be expanded to /usr/lib/prolog/demo/myfile. The second argument of file_search_path/2 may be another alias.

Below is the initial definition of the file search path. This path implies swi(<Path>) and refers to a file in the SWI-Prolog home directory. The alias foreign(<Path>) is intended for storing shared libraries (.so or .DLL files). See also use_foreign_library/1. 

user:(file_search_path(library, Dir) :-
        library_directory(Dir)).
user:file_search_path(swi, Home) :-
    current_prolog_flag(home, Home).
user:file_search_path(swi, Home) :-
    current_prolog_flag(shared_home, Home).
user:file_search_path(library, app_config(lib)).
user:file_search_path(library, swi(library)).
user:file_search_path(library, swi(library/clp)).
user:file_search_path(foreign, swi(ArchLib)) :-
    current_prolog_flag(apple_universal_binary, true),
    ArchLib = 'lib/fat-darwin'.
user:file_search_path(foreign, swi(ArchLib)) :-
    \+ current_prolog_flag(windows, true),
    current_prolog_flag(arch, Arch),
    atom_concat('lib/', Arch, ArchLib).
user:file_search_path(foreign, swi(ArchLib)) :-
    current_prolog_flag(msys2, true),
    current_prolog_flag(arch, Arch),
    atomic_list_concat([lib, Arch], /, ArchLib).
user:file_search_path(foreign, swi(SoLib)) :-
    current_prolog_flag(msys2, true),
    current_prolog_flag(arch, Arch),
    atomic_list_concat([bin, Arch], /, SoLib).
user:file_search_path(foreign, swi(SoLib)) :-
    (   current_prolog_flag(windows, true)
    ->  SoLib = bin
    ;   SoLib = lib
    ).
user:file_search_path(path, Dir) :-
    getenv('PATH', Path),
    (   current_prolog_flag(windows, true)
    ->  atomic_list_concat(Dirs, (;), Path)
    ;   atomic_list_concat(Dirs, :, Path)
    ),
    '$member'(Dir, Dirs).
user:file_search_path(user_app_data, Dir) :-
    '$xdg_prolog_directory'(data, Dir).
user:file_search_path(common_app_data, Dir) :-
    '$xdg_prolog_directory'(common_data, Dir).
user:file_search_path(user_app_config, Dir) :-
    '$xdg_prolog_directory'(config, Dir).
user:file_search_path(common_app_config, Dir) :-
    '$xdg_prolog_directory'(common_config, Dir).
user:file_search_path(app_data, user_app_data('.')).
user:file_search_path(app_data, common_app_data('.')).
user:file_search_path(app_config, user_app_config('.')).
user:file_search_path(app_config, common_app_config('.')).
user:file_search_path(app, swi(app)).
user:file_search_path(app, app_data(app)).

The '$xdg_prolog_directory'/2 uses either the XDG Base Directory or win_folder/2 on Windows. On Windows, user config is mapped to roaming appdata (CSIDL_APPDATA), user data to the non-roaming (CSIDL_LOCAL_APPDATA) and common data to (CSIDL_COMMON_APPDATA).

The file_search_path/2 expansion is used by all loading predicates as well as by absolute_file_name/[2,3].

The Prolog flag verbose_file_search can be set to true to help debugging Prolog's search for files.

Examples

Using absolute_file_name/3 to find files

Using absolute_file_name/3 to find files

With swipl started from /home/janw/src/swipl-devel/library/:

?- absolute_file_name('lists.pl', Abs, [access(read)]).
Abs = '/home/janw/src/swipl-devel/library/lists.pl'.

Using a search path from any directory. Using file_type(prolog) sets the extensions to search for.

?- absolute_file_name(library(lists)', Abs,
                      [access(read), file_type(prolog)]).
Abs = '/home/janw/src/swipl-devel/library/lists.pl'.
?- absolute_file_name(path(ls), Abs, [access(execute)]).
Abs = '/bin/ls'.

We can create our own search path using file_search_path/2. In this example we define two places to search for data files. Search happens in the order in which file_search_path/2 generates answers.

:- multifile user:file_search_path/2.

user:file_search_path(data, MyData) :-
    expand_file_name('~/data', [MyData]).
user:file_search_path(data, '/usr/local/share/data').
?- absolute_file_name(data(myfile), Abs, [access(read)]).
Abs = '/home/janw/data/myfile'.
Tags are associated to your profile if you are logged in|Report abuse
Tags:
  • file_path
LogicalCaptain said (2016-12-15T13:56:44):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

The definition should be "file_search_path(?Alias, ?Path)" as the following works perfectly well (?):

?- findall([X,Y],file_search_path(X,Y),Bag).
Bag = [[library, '/usr/lib64/swipl-7.2.3/library'],
[library, '/usr/lib64/swipl-7.2.3/library/clp'],
[swi, '/usr/lib64/swipl-7.2.3'],
[foreign, swi('lib/x86_64-linux')],
[foreign, swi(lib)],
[path, '/usr/local/java/maven/bin'],
[path, '/usr/local/java/gradle/bin'], [path|...], [...|...]|...].

And here is how to add your path:

assertz(file_search_path(mine,'/home/quux')).
LogicalCaptain said (2016-12-15T15:56:49):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

Thanks @Jan. But the mode of file_search_path/2 cannot be +,- as you must be able to set aliases with mode +,+ ? (Prolog with at least mode, if not type annotations when?)

It's not a hook only either, as it replaces library_directory/1 ?

Jan Wielemaker said (2016-12-15T14:08:26):0 upvotes 0 0 downvotes
Picture of user Jan Wielemaker.
No. This is a hook that is called by absolute_file_name/2 with the mode +,-. (so yes, the mode is wrong, but should be +,-). The user definition does not need to support other modes and calling it with other modes may or may not work, depending on the user supplied definition.