SWI-Prolog Did You Know Did you know? This website's code is available Search Documentation:
Predicate close/1
Availability:built-in
[ISO]close(+Stream)
Close the specified stream. If Stream is not open, an existence error is raised. See stream_pair/3 for the implications of closing a stream pair.

If the closed stream is the current input, output or error stream, the stream alias is bound to the initial standard I/O streams of the process. Calling close/1 on the initial standard I/O streams of the process is a no-op for an input stream and flushes an output stream without closing it.102This behaviour was defined with purely interactive usage of Prolog in mind. Applications should not count on this behaviour. Future versions may allow for closing the initial standard I/O streams.

Examples

Read all lines to a list

Read all lines to a list

file_lines(File, Lines) :-
    setup_call_cleanup(open(File, read, In),
       stream_lines(In, Lines),
       close(In)).

stream_lines(In, Lines) :-
    read_string(In, _, Str),
    split_string(Str, "\n", "", Lines).

This loads all lines to memory as strings. If we use the Unix dictionary words:

?- file_lines("/usr/share/dict/words", Lines).
Words = ["A", "a", "aa", "aal", "aalii", "aam", "Aani", "aardvark", "aardwolf"|...].
Backtrack over lines in a file

Backtrack over lines in a file

file_line(File, Line) :-
    setup_call_cleanup(open(File, read, In),
        stream_line(In, Line),
        close(In)).

stream_line(In, Line) :-
    repeat,
    (   read_line_to_string(In, Line0),
        Line0 \== end_of_file
    ->  Line0 = Line
    ;   !,
        fail
    ).

This will backtrack over consecutive lines in the input. If we use the Unix dictionary words:

?- file_line("/usr/share/dict/words", Word).
Word = "A" ;
Word = "a" ;
Word = "aa" ;
Word = "aal" ; % and so on

This doesn't load all lines to memory, so it can be used with very large files.

See also
- read_line_to_codes/2 to read to a code list instead of a string
- read_string/5 for more control over the separator and stripping
Tags are associated to your profile if you are logged in
Tags:
LogicalCaptain said (2021-06-08T16:30:56):0 upvotes 0 0 downvotes
Picture of user LogicalCaptain.

"If Stream is not open, an existence error is raised."

So closing a stream is not idempotent as you get an exception on the second call:

?-
open('/etc/motd','read',Stream),close(Stream),close(Stream).
ERROR: stream `<stream>(0x19fb860)' does not exist (already closed)

This is often not what one wants. A stream may be closed from several places in the call stack after operations are done.

The solution is of course:

idempotent_close(Stream) :-
   is_stream(Stream) -> close(Stream) ; true.

Then:

?-
open('/etc/motd','read',Stream),idempotent_close(Stream), idempotent_close(Stream).
Stream = <stream>(0x19fbc30).

Note that the stream "blob" retains the quality of identifying a stream after the stream has been closed:

?- open("/etc/motd",read,Stream),
   is_stream(Stream),
   atomic(Stream),
   blob(Stream,T),
   close(Stream),
   blob(Stream,TT).
Stream = <stream>(0x29db6b0),
T = TT, TT = stream.